**Case Study of a Misspecified Model**

A total of 36 healthy volunteers (6 subjects per dose) were given a single dose of Drug X at doses of 0, 100, 500, 750, 1000, 1500, and 1750 mg. Pharmacokinetic samples and ECGs were collected at 0, 0.5, 1, 2, 3, 4, 6, 8, 12, and 24 h after dosing. In total, 324 observations were available for analysis. Pharmacokinetic samples were analyzed for Drug X concentrations. ECGs were overread by a cardiologist in triplicate and the mean QTcF interval values reported for each subject at each time point. The baseline predose QTcF interval was 398 msec (range: 372 to 419 msec). Time zero values were removed from the dataset after single-correction. A spaghetti plot of Drug X concentrations and dQTcF intervals is shown below:

|  |  |
| --- | --- |
| The SGPanel Procedure | The SGPanel Procedure |

The Drug X concentration-dQTcF interval data were analyzed using the methods presented in this white paper. An exploratory plot of dQTcF intervals plotted against Drug X concentrations is shown below. Included is a LOESS nonparametric smooth fit, naïve linear regression fit, naïve linear mixed effect model fit and naïve Emax model fit using only drug concentration as the independent variable. The exploratory plot suggests a curvilinear relationship between dQTcF intervals and drug concentrations with mean maximal values of around 15 msec.

|  |
| --- |
| The SGPlot Procedure |

The data were analyzed using the methods described in this white paper using the NLMIXED procedure in SAS. Two competing models were examined, one where the relationship between drug concentrations and dQTcF intervals was linear and one where the relationship was modeled using an Emax model. Both models had difficulty estimating the covariance between the random effects so these parameters were set equal to 0. The models are compared below:

|  |  |  |  |  |
| --- | --- | --- | --- | --- |
|  | **Linear Model** | | **Nonlinear Model** | |
| -2LL | 1910.8 | | 1879.6 | |
| AIC | 1940.8 | | 1911.6 | |
| AICc | 1942.4 | | 1913.4 | |
|  |  | |  | |
| **Parameters** | **Estimate** | **Std Error** | **Estimate** | **Std Error** |
| Intercept | -1.90 | 1.88 | -1.92 | 1.29 |
| Treatment Effect | 9.52 | 2.21 | -1.00 | 2.78 |
| Time Effect (0.5 h) | 0.074 | 1.00 | 0.16 | 0.96 |
| Time Effect (1 h) | -0.33 | 0.94 | -0.81 | 0.92 |
| Time Effect (2 h) | -0.043 | 0.97 | -0.66 | 0.93 |
| Time Effect (3 h) | 0.032 | 1.02 | -0.36 | 0.95 |
| Time Effect (4 h) | 0.10 | 1.04 | -0.52 | 0.95 |
| Time Effect (6 h) | -0.53 | 1.04 | -1.00 | 0.95 |
| Time Effect (8 h) | 0.49 | 1.02 | 0.05 | 0.94 |
| Time Effect (12 h) | 0.32 | 0.98 | -0.42 | 0.93 |
| Time Effect (24 h) | 0 | --- | 0 | --- |
| Change from Baseline Effect | -0.064 | 0.08 | -0.10 | 0.06 |
| Concentration Effect (linear) | 0.00308 | 0.000852 |  |  |
| Concentration Effect (Emax) |  |  | 23.81 | 2.85 |
| Concentration Effect (EC50) |  |  | 486.41 | 175.91 |
|  |  | |  | |
| **Variance Components** | **Estimate** | | **Estimate** | |
| Variance (Intercept) | 17.0 | | 5.9 | |
| Variance (Concentration linear) | 1.78E-6 | | --- | |
| Variance (Emax) | --- | | 6.00 | |
| Variance (EC50) | --- | | 21.5 | |
| Residual Variance | 15.7 | | 15.2 | |

The model parameter estimates indicated that inclusion of treatment effect as a fixed effect in the linear model improved the goodness of fit and was statistically significant (p<0.0001). Both nominal time (p=0.9650) and change from baseline (p=0.4132) were not significant and did not improve the linear model. In contrast, neither the treatment effect (p=0.7227) nor change from baseline (p=0.1252) were significant in the nonlinear model. In both models, the inclusion of a drug effect in the model was statistically significant (p < 0.001). Because the models were not nested it was not appropriate to compare the models using the likelihood ratio test. However, it was appropriate to compare the models using information criteria. The nonlinear model resulted in a decrease of the AIC and AICc of 29.2 and 29.0, respectively, compared to the linear model. Both criteria indicated that the nonlinear Emax model was superior to the linear model.

In both models, the residuals were centered at zero and the Anderson-Darling test for the distribution of the residuals was not significant, indicating that the residuals were consistent with a normal distribution. A comparison of the residual plots (shown below) showed that, although the Emax model was superior to the linear model in terms of information criteria, the goodness of fit plots were quite similar. Only the plot of standardized residuals against drug concentrations was sensitive enough to detect a difference between the models, with the nonlinear model showing less systematic deviation from the zero reference line than the linear model.

| **Residual Plots** | |
| --- | --- |
| **Linear Model** | **Nonlinear Emax model** |
| Histogram for Standardized_Residuals | Histogram for Standardized_Residuals |
| Q-Q plot for Standardized_Residuals | Q-Q plot for Standardized_Residuals |
| The SGPlot Procedure | The SGPlot Procedure |
| The SGPlot Procedure | The SGPlot Procedure |
| The SGPlot Procedure | The SGPlot Procedure |

One plot that was sensitive to model misspecification was the decile plot. In this plot the observed drug concentrations are categorized into their decile (10 bins of equal size) and the mean change from baseline QTcF intervals are calculated for each bin, along with their 5th and 95th percentiles, as well as the 90% confidence interval for the mean. A simulation-based predictive check is then performed. Simulated concentrations were varied from 0 to 4000 ng/mL by 100 ng/mL increments. Random draws are made from the sampling distribution of the parameter estimates fixing the residual error and random effects to zero. This will ultimately generate the light purple band in the figure, which represents the confidence interval around the mean predicted dQTcF interval. The SAS code below shows the details. See Kummel, Dingemnase, and Krause (2017) for details on confidence intervals and prediction intervals in mixed effect models. For a well predicting model, the mean predictions (solid black line) should capture the general trend of the observed mean values. In this example, the linear model clearly does not capture the trend of the data like the Emax model does. The mean observed data and the simulated mean under the Emax model were quite similar and manifestly shows that it was superior to the linear mixed effect model.

| **Decile Plot** | |
| --- | --- |
| **Linear Model** | **Nonlinear Emax model** |
| The SGPlot Procedure | The SGPlot Procedure |
| Legend: The observed mean dQTcF interval within each bin are the solid blue circles. The solid black line is the mean predicted dQTcF interval. The smaller, more narrow, solid error bars are the confidence intervals for the mean dQTcF interval within each bin, while the wider, dashed error bars are the percentiles of the observed dQTcF intervals within the bin. The light purple band is the 90% confidence interval of the mean predicted dQTcF interval. | |

In summary, this example illustrates the difficulties sometimes encountered with model selection when choosing between a linear and nonlinear model. Model selection requires careful review of the model selection criteria, the parameter estimates, residual plots, and other diagnostic plots.

# References

Kummel A, Dingemanse J, and Krause A. Confidence and prediction intervals for regression model functions. Submitted to Pharmaceutical Statistics, 2017.

# Simulation and Analysis Conditions

The data presented in this example were generated using Monte Carlo simulation. Using simulation, as opposed to actual experimental data, the true data generating model is known and the performance of a correctly specified and misspecified model can be directly compared.

The experimental design was that of a single ascending dose design. Subjects were randomized to one of five dose levels: 0, 100, 500, 750, and 1000 mg with 8 subjects per dose. Pharmacokinetic and ECG samples were sampled under a single ascending dose design and were collected at 0, 0.5, 1, 2, 3, 4, 6, 8, 12, and 24 h after dosing. Pharmacokinetic data were simulated from a 1-compartment model with first order absorption. The population mean clearance (CL), volume of distribution (V), and first order absorption rate constant (KA) were 12 L/h, 400 L, and 0.7 per h, with 32% between-subject variability for each parameter. True drug concentrations were simulated by:



Observed concentrations (CONC) were simulated by adding log-normal error with 10% coefficient of variation (CV).

Single-delta corrected QTc intervals (dQTc) at each nominal time point were simulated from the following model:

.

TRT was defined as 0 for placebo, 1 for active drug. Time1-Time8 was a binary 0/1 variable for nominal time with



Baseline QTcF intervals were simulated for each subject from a normal distribution with mean 400 msec and standard deviation of 12 msec. DrugEffect was defined as either a linear model of the form:



Or an Emax-type model of the form:



The following parameters were simulated for each subject. Emax (θ11) was normally distributed with mean 20 msec and standard deviation 2 msec. EC50 (θ12) was log-normally distributed with mean 400 ng/mL and 22% CV. The intercept (θ1) in Eq. was normally distributed with mean -2.5 msec and standard deviation 4 msec. The treatment effect (θ2) in Eq. was normally distributed with mean 0 msec and standard deviation 0.2 msec. The change from baseline effect (θ12) was defined as a normally distributed random variable with mean -0.1 and standard deviation 0.02 msec. The θ values for each time effect parameter were simulated as a standard normal random variate:



Where P was equal to 0, 0.1, -0.2, 0.3, 0.1, -0.3, 0.1, 0.05, and -0.2, respectively, with R=0.2 for all time effects. Randomly distributed error in Eq. was normally distributed with mean 0 and standard deviation of 4 msec. dQTc intervals and observed drug concentrations were rounded two places behind the decimal.

Simulated observed concentration (Eq. with random error) and dQTc intervals (Eq. ) were modeled using a linear mixed effect and nonlinear mixed effect model using the NLMIXED procedure in SAS. The data are stored in the working dataset concqt. The following SAS code was used to analyze the data using a linear mixed effect model:

**proc** **nlmixed** data=concqt;

parms theta1=-**3.7**, theta2=**8.1**, theta3=-**0.6**, theta4=**0.8**, theta5=**0.3**, theta6=**0.8**,

theta7=-**0.9**, theta8=-**0.7**, theta9=**0.9**, theta10=-**0.3**, theta11=**0.1**, theta12=**0**, std1=**2.2**,

std2=**0.001**, sigma=**5**;

bounds std1>**0**, std2>**0**, sigma > **0**;

intercept = theta1 + eta1;

slope = theta12 + eta2;

drugeffect = slope\*dv;

pred = intercept + theta2\*trt + theta3\*time1 + theta4\*time2 + theta5\*time3 + theta6\*time4

+ theta7\*time5 + theta8\*time6 + theta9\*time7 + theta10\*time8 + theta11\*chgbase +

drugeffect;

residuals = pred - dqtcf;

model dqtcf ~ normal(pred, sigma\*sigma);

estimate 'Variance(ETA1)' std1\*std1;

estimate 'Variance(ETA2)' std2\*std2;

estimate 'Residual Variance' sigma\*sigma;

random eta1 eta2 ~ normal([**0**,**0**], [std1\*std1, **0**, std2\*std2]) subject=sid;

predict pred out=pred;

predict residuals out=residuals;  
 ods output parameterestimates=parms;

**run**; **quit**;

The following SAS code was used to analyze the data using a nonlinear mixed effect model:

**proc** **nlmixed** data=concqt;

parms theta1=-**3.5**, theta2=**12**, theta3=**0**, theta4=**0**, theta5=**0**, theta6=**0**, theta7=**0**, theta8=**0**, theta9=**0**, theta10=**0**, theta11=**0.1**, theta12=**20**, theta13=**200**, std1=**2.2**, std2=**0.001**, sigma=**5**;

bounds std1>**0**, std2>**0**, sigma > **0**;

intercept = theta1 + eta1;

emax = theta12 + eta2;

ec50 = theta13;

if conc = **0** then drugeffect = **0**; else drugeffect = emax\*dv/(ec50 + dv);

pred = intercept + theta2\*trt + theta3\*time1 + theta4\*time2 + theta5\*time3 + theta6\*time4

+ theta7\*time5 + theta8\*time6 + theta9\*time7 + theta10\*time8 + theta11\*chgbase +   
 drugeffect;

residuals = pred - dqtcf;

model dqtcf ~ normal(pred, sigma\*sigma);

random eta1 eta2 ~ normal([**0**,**0**], [std1\*std1, **0**, std2\*std2]) subject=sid;

estimate 'Variance(ETA1)' std1\*std1;

estimate 'Variance(ETA2)' std2\*std2;

estimate 'Residual Variance' sigma\*sigma;

predict pred out=pred;

predict residuals out=residuals;

ods output parameterestimates=parms;

**run**; **quit**;

The following SAS code was used to create the decile plots based on the nonlinear mixed effect model:

\*\*\* Compute deciles for observed concentrations;

**proc** **univariate** data=concqt;

var conc;

output out=deciles pctlpre=deciles pctlpts=**0** to **100** by **10**;

**run**; **quit**;

**data** deciles; set deciles; index = **1**; **proc** **sort**; by index; **run**; **quit**;

\*\*\* merge and determine which decile each observation is within;

**data** set1;

merge concqt deciles;

by index;

decile = **1**;

if conc > deciles10 and conc <= deciles20 then decile = **2**;

if conc > deciles20 and conc <= deciles30 then decile = **3**;

if conc > deciles30 and conc <= deciles40 then decile = **4**;

if conc > deciles40 and conc <= deciles50 then decile = **5**;

if conc > deciles50 and conc <= deciles60 then decile = **6**;

if conc > deciles60 and conc <= deciles70 then decile = **7**;

if conc > deciles70 and conc <= deciles80 then decile = **8**;

if conc > deciles80 and conc <= deciles90 then decile = **9**;

if conc > deciles90 and conc <= deciles100 then decile = **10**;

**proc** **sort**; by decile; **run**; **quit**;

\*\*\* Compute means and percentiles of observed data by decile;

**proc** **means** data=set1 alpha=**0.10** mean std stderr clm n noprint;

var dqtcf conc;

by decile;

output out=mean mean=obsmean meanconc p5=obsp5 p95=obsp95 lclm=obslowerclm uclm=obsupperclm;

**run**; **quit**;

\*\*\*\* Transpose parameters and standard errors into 1 row of n parameters;

**proc** **transpose** data=parms out=parmst; var estimate; id parameter; **run**; **quit**;

**data** parmst; set parmst; index = **1**; **proc** **sort**; by index; **run**; **quit**;

**proc** **transpose** data=parms out=parmset prefix=se\_; var standarderror; id parameter; **run**; **quit**;

**data** parmset; set parmset; index = **1**; **proc** **sort**; by index; **run**; **quit**;

\*\*\* merge transposed parameters and simulate observations;

**data** sim;

merge parmst parmset deciles;

do simconc = **0** to **4000** by **100**;

do sim = **1** to **1000**;

theta2a = theta2 + rannor(**2345223**)\*se\_theta2;

theta12a = theta12 + rannor(**2345213**)\*se\_theta12;

theta13a = theta13 + rannor(**2345213**)\*se\_theta13;

simCIdQTcF = theta2a + theta12a\*simconc/(theta13a + simconc);

decile = **1**;

if simconc > deciles10 and simconc <= deciles20 then decile = **2**;

if simconc > deciles20 and simconc <= deciles30 then decile = **3**;

if simconc > deciles30 and simconc <= deciles40 then decile = **4**;

if simconc > deciles40 and simconc <= deciles50 then decile = **5**;

if simconc > deciles50 and simconc <= deciles60 then decile = **6**;

if simconc > deciles60 and simconc <= deciles70 then decile = **7**;

if simconc > deciles70 and simconc <= deciles80 then decile = **8**;

if simconc > deciles80 and simconc <= deciles90 then decile = **9**;

if simconc > deciles90 then decile = **10**;

output;

end;

end;

**proc** **sort**; by decile; **run**; **quit**;

\*\*\* compute the means of the simulated observations;

**proc** **means** data=sim noprint alpha=**0.10**;

var simCIdQTcF simconc;

by decile;

output out=simpercentiles mean=cimean meansimconc p5=cip5 p95=cip95;

**run**; **quit**;

\*\*\* merge observed and simulation data for plotting;

**data** decileplot;

merge mean simpercentiles;

by decile;

**run**; **quit**;

ods graphics on/ reset width=**6** in border=off reset=index;

ods html style=statistical image\_dpi =**200**;

**proc** **sgplot** data=decileplot noautolegend;

band x=meansimconc lower=cip5 upper=cip95 / fillattrs=(color="verylightblue");

scatter x=meanconc y=obsmean / yerrorlower=obslowerclm yerrorupper=obsupperclm   
 markerattrs=(color=blue symbol=circlefilled size=**10**) errorbarattrs=(color=blue   
 thickness=**2**);

scatter x=meanconc y=obsmean / yerrorlower=obsp5 yerrorupper=obsp95 markerattrs=(color=blue

symbol=circlefilled size=**10**) errorbarattrs=(color=blue thickness=**2** pattern=**2**);

series x=simconc y=CImean / lineattrs=(color=black thickness=**3**);

yaxis label="Change from Baseline QTcF Interval (msec)" grid;

xaxis label="Drug Concentration";

**run**; **quit**;

ods html close;